[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

20030828: radar product generation scripts?



Chris,

Attatched is the script in question.

For mosaics, see the GDRADR information under:
http://my.unidata.ucar.edu/content/software/gempak/examples/gdradr/

(of course, gdradr and nex2gini operate similarly).

Steve Chiswell

**************************************************************************
Unidata User Support                                    UCAR Unidata Program
303 497 8643                                                  P.O. Box 3000
address@hidden                                   Boulder, CO 80307
----------------------------------------------------------------------------
Unidata WWW Service              http://my.unidata.ucar.edu/content/support
****************************************************************************

On Fri, 22 Aug 2003, Chris Herbster wrote:

> Hi all,
>
> I hope that all is well in CO.  Things are getting ready to crank up
> with the fall semester approaching and we are getting ALL 72 new Dell
> 260's with 2.4 GHz, 1GB DDR RAM and they fly!  Vroom, Vroom!  Everything
> (esp the IDV) is great!  All this and Internet2 giving us great throughput!
>
> Anyway, just wanted to share the good news and brag a little.  (-:
>
> On to the subject of the email ....
>
> We are putting together some data products on our web site for the local
> community and wanted to include the local MLB radar.  I noticed a pqact
> entry that exists on your end to do this for your local radar and was
> wondering if you might share this?  This way I can see a "good" example
> of how to work with the LDM for more scripts I want to write down the
> road.  (Pretty please.)
>
> The pqact entry is:
>
> # make some nids gifs
> ##NEXRAD        SDUS5. ....
> ([0-3][0-9])([0-2][0-9])([0-6][0-9]).*/p(N0[RV])(MLB)
> ##      EXEC    util/NEXRAD_gif.csh \5 \4 (\1:yyyy)(\1:mm)\1_\2\3
> #
>
> You can see that I've already got the site id set for our neighborhood.  (-:
>
> Also, I'd like to generate the same products that you are for the
> composite FNEXRAD feeds (possible future source for others as we now
> have fat network pipes, and spare horsepower).  Could you please share
> your configs for that too?  (pretty please, with sugar on top?)
>
> Thanks in advance!
>
> Best wishes to all!
>
> Cheers,
>
> Chris H.
>
> --
>
>  Dr. Christopher G. Herbster
>  Assistant Professor
>  Director of ERAU Weather Center
>  Applied Aviation Sciences
>  Embry-Riddle Aeronautical Univ.
>  600 S. Clyde Morris Blvd.
>  Daytona Beach, FL 32114-3900
>
>  386.226.6444 Office
>  386.226.6446 Weather Center
>  http://wx.erau.edu/
>
>
>
#!/bin/csh -f

setenv PATH /bin:/usr/bin:/usr/local/bin:/usr/sbin:/usr/ucb:.:/usr/local/ldm/bin

source /home/gempak/Gemenviron

set SITE=$1
set TYPE=$2
set DATTIM=$3

set FILENAME=${TYPE}_${DATTIM}
set GIFFILE=${SITE}_${TYPE}_${DATTIM}.gif

#
# Make sure the NEXRAD file exists before seting lock
#
@ COUNT = 0
while (! -e $RAD/NIDS/${SITE}/${TYPE}/${FILENAME} )
   sleep 2
   @ COUNT = $COUNT + 1
   if($COUNT == 60) then
      echo "`hostname`: Could not find ${SITE}/${TYPE}/${FILENAME} for nids 
generation" | \
         /usr/bin/mailx -s NIDS chiz
      exit 0
   endif
end

#
# change to working directory and set lock...wait until older locks are removed
#
cd /usr/local/ldm/data/gempak/web

set LOCK=.inuse.$$
touch $LOCK

@ COUNT = 0
set TEST=`ls -rt .inuse.* | head -1`
set OFFENDING=$TEST
while(($TEST != $LOCK)&&($COUNT < 61))
   sleep 4
   set TEST=`ls -rt .inuse.* | head -1`
   if ( ( $COUNT == 50 ) && ( $TEST == $OFFENDING ) ) then
      # this lock has been around a really long time. Maybe its toast.
      rm -f $OFFENDING
   endif
   if($COUNT == 60) then
      echo "Please check `hostname` on $TEST for nids generation $SITE $TYPE 
$DATTIM" | \
         /usr/bin/mailx -s NIDS chiz
      rm $LOCK
      exit 0
   endif
   @ COUNT = $COUNT + 1
end

if(-e ${GIFFILE}) rm -f $GIFFILE

set TITLE="NIDS $SITE $TYPE  ${DATTIM}"

if($TYPE == 'N0R') then
   set TITLE="NIDS $SITE Base Reflectivity  ${DATTIM}"
endif
if($TYPE == 'N0V') then
   set TITLE="NIDS $SITE Radial Velocity  ${DATTIM}"
endif
if($TYPE == 'N0S') then
   set TITLE="NIDS $SITE Storm Relative Velocity  ${DATTIM}"
endif

gpmap_gif << EOF
 \$mapfil = hicnus.uni+hipowo.cia+rdus.uni+rdis.uni
 MAP      = 8/1/1+1/1/2+15/1/1+2/1/2
 GAREA    = dset
 PROJ     = rad
 SATFIL   = 
 RADFIL   = \$RAD/NIDS/${SITE}/${TYPE}/${FILENAME}
 LATLON   = 0
 PANEL    = 0
 TITLE    = 5/-1/$TITLE
 TEXT     = 1/22/1/hw
 CLEAR    = y
 DEVICE   = gif|${GIFFILE}|900;700
 !LUTFIL   = osf_ref16.tbl
 LUTFIL   = default
 STNPLT   = 5|0|disco_sites.tbl
 r

 e
EOF


set LAST=${SITE}_${TYPE}
if(-e $GIFFILE) then
   if(-e $LAST.gif) rm -f $LAST.gif
   mv $GIFFILE $LAST.gif
else
   echo "failed to generate $GIFFILE $LAST.gif on `hostname` for nids 
generation: $FILENAME" | \
   /usr/bin/mailx -s NIDS chiz
endif

rm -f $LOCK

exit 0